
Nebulex.Adapters.Local 
    



      
A generational, in-memory cache adapter for Nebulex, inspired by
epocxy cache.
The adapter keeps up to two active generations, newer and older. Each
generation uses one ETS table, or several tables with the :shards backend.
Fetches check the newer generation first. When an unexpired entry is found
in the older generation, the adapter moves it into the newer one. When a new generation
is created, the newer generation becomes the older one, and the previous
older generation is retired; its tables are deleted after
:gc_cleanup_delay. This evicts entries in groups, without a timer per
entry.
See Nebulex.Adapters.Local.Generation for details on generation
management and garbage collection.
Features
	Configurable backend (:ets or :shards).
	Expiration through the :ttl option. Fetches exclude expired entries
(see The :ttl option).
	Eviction by generational garbage collection (see
Nebulex.Adapters.Local.Generation).
	Sharding for intensive workloads, with the :shards backend and the
:partitions option.
	Transactions through Nebulex.Locks, which keeps the locks in ETS on
the local node. See Nebulex.Adapter.Transaction.
	Stats.
	Retries when the garbage collector deletes a generation table during an
operation (see Concurrency and resilience).

Concurrency and resilience
The garbage collector can delete a generation table while an operation still
holds a reference to it. Accessing that table raises ArgumentError on the
ETS backend, or {:unknown_table, tab} on the :shards backend.
Cache operations catch these errors, reload the generation references from
the metadata table, and retry up to 3 times, waiting 10 ms before each retry.
If the last retry fails too, the error propagates to the caller. Streams
built from match-spec queries are not retried, because they read the tables
lazily while the stream is consumed; streams with {:in, keys} retry each
chunk of keys.
The :gc_cleanup_delay option (10 seconds by default) gives in-flight
operations time to finish before their tables are deleted. When a new
generation is created, the oldest one is removed from the active generations
at once, but its tables are deleted only after the delay. The delay does not
keep the retired entries available to new operations.
Configuration options
The following options can be used to configure the adapter:
	:cache (atom/0) - Required. The defined cache module.

	:stats (boolean/0) - A flag to determine whether to collect cache stats. The default value is true.

	:backend (backend/0) - The backend or storage to be used for the adapter. The default value is :ets.

	:read_concurrency (boolean/0) - Sets the ETS :read_concurrency option for each generation table. See
:ets.new/2. The default value is true.

	:write_concurrency (boolean/0) - Sets the ETS :write_concurrency option for each generation table. See
:ets.new/2. The default value is true.

	:compressed (boolean/0) - Sets the ETS :compressed option for each generation table. See
:ets.new/2. The default value is false.

	:backend_type - The ETS table type for each generation table. See :ets.new/2. The default value is :set.

	:partitions (pos_integer/0) - The number of ETS partitions when using the :shards backend.
See :shards.new/2.
The default value is System.schedulers_online().

	:purge_chunk_size (pos_integer/0) - This option is deprecated. It is ignored and will be removed in the next major release. Deprecated: This option is no longer used and will be removed in the
next major release. Purging the older generation on put_all and
put_new_all is now done with per-key deletes.

	:gc_interval (pos_integer/0) - The interval between scheduled generation rotations, in milliseconds. If
omitted, periodic rotation is disabled. Size or memory checks can still
trigger rotations, and you can create a generation explicitly with
MyCache.new_generation/1.
Usage
Set :gc_interval unless you want to rotate generations yourself.
Without it, entries that are never fetched stay in the cache until a
size or memory check or an explicit call creates a new generation.

	:max_size (pos_integer/0) - The entry-count threshold that triggers a generation rotation during a
size check. If omitted, entry-count checks are disabled.

	:allocated_memory (pos_integer/0) - The memory threshold, in bytes, that triggers a generation rotation
during a memory check. If omitted, memory checks are disabled.

	:gc_memory_check_interval (mem_check_interval/0) - The interval time in milliseconds for garbage collection to run the size
and memory checks.
Usage
Beware: For the :gc_memory_check_interval option to work, you must
configure one of :max_size or :allocated_memory (or both).
The default value is 10000.

	:gc_cleanup_delay (pos_integer/0) - The delay in milliseconds before the oldest generation is deleted.
This grace period allows ongoing operations to complete before the
generation is removed. The default value is 10000.

	:lock_opts (keyword/0) - Options to customize the locks manager used for cache transactions.
The local adapter uses Nebulex.Locks for implementing transactions with
an ETS-based locking mechanism optimized for single-node scenarios. This
option allows you to customize the behavior of the locks manager, such as
adjusting the cleanup interval or batch size for stale lock cleanup.
Available Options:
	:cleanup_interval - The interval in milliseconds for periodic
cleanup of stale locks (defaults to 5 minutes).
	:cleanup_batch_size - The number of locks to process per batch
during cleanup (defaults to 100).

Note: The :name and :init_callback options are managed internally by
the adapter and should not be provided. See the "Start Options" section
in Nebulex.Locks for all available options.
Examples:
# Use default lock options (recommended for most cases)
MyCache.start_link()

# Customize cleanup for high-throughput scenarios
MyCache.start_link(
  lock_opts: [
    cleanup_interval: :timer.minutes(1),
    cleanup_batch_size: 500
  ]
)

# More frequent cleanup for memory-constrained environments
MyCache.start_link(
  lock_opts: [
    cleanup_interval: :timer.seconds(30)
  ]
)
The default value is [].


Usage
Define a cache module:
defmodule MyApp.LocalCache do
  use Nebulex.Cache,
    otp_app: :my_app,
    adapter: Nebulex.Adapters.Local
end
Configure the cache in your application environment, usually in
config/config.exs:
config :my_app, MyApp.LocalCache,
  gc_interval: :timer.hours(12),
  max_size: 1_000_000,
  allocated_memory: 2_000_000_000,
  gc_memory_check_interval: :timer.seconds(10)
For intensive workloads, use the :shards backend to partition the cache
across several ETS tables. Set the number of partitions with :partitions
(defaults to System.schedulers_online()):
config :my_app, MyApp.LocalCache,
  backend: :shards,
  gc_interval: :timer.hours(12),
  max_size: 1_000_000,
  allocated_memory: 2_000_000_000,
  gc_memory_check_interval: :timer.seconds(10),
  partitions: System.schedulers_online() * 2
Add the cache to your application's supervision tree, usually in
lib/my_app/application.ex:
def start(_type, _args) do
  children = [
    MyApp.LocalCache
  ]

  opts = [strategy: :one_for_one, name: MyApp.Supervisor]

  Supervisor.start_link(children, opts)
end
See Nebulex.Cache for more information.
The :ttl option
The :ttl option sets an entry's expiration time. Fetches check this time
and exclude expired entries. Expiration does not schedule a timer to remove
an entry when its TTL ends, so the TTL is not an eviction mechanism;
configure the GC options for that. See the
"Eviction policy" section. Custom match-spec
queries need their own expiration conditions.
Generation rotation can evict an entry before its TTL ends, so a TTL does
not guarantee that an entry stays cached that long.
Eviction policy
The adapter evicts entries by retiring the oldest generation. Fetching an
entry from the older generation moves it into the newer one, so it survives
the next rotation. This approximates eviction by recent access; the adapter
does not keep an exact LRU order or count how often entries are accessed.
The garbage collector creates a new generation, retiring the oldest one:
	Every :gc_interval. With periodic rotation alone, an entry that is
written and never read stays available for one to two :gc_interval
periods, depending on when it was written.

	When a size or memory check finds that :max_size or
:allocated_memory is reached or exceeded. The checks run every
:gc_memory_check_interval when either option is set, and can evict
entries sooner than the periodic rotation.


Configuring the GC options
Set :gc_interval to control how often the cache rotates generations.
Shorter intervals evict unread entries sooner; longer intervals keep them
longer. For example, with gc_interval: :timer.hours(12) and periodic
rotation alone, an entry written once and never fetched is evicted after
roughly 12 to 24 hours. Expiration or additional rotations can make it
unavailable sooner.
Set :max_size, :allocated_memory, or both to trigger extra rotations
when the cache reaches that size. Choose the values from the expected number
and size of entries and the memory available to your application.
These thresholds are checked periodically, so they are not hard limits: the
cache can exceed them between checks, and retired tables stay allocated
until they are deleted after :gc_cleanup_delay. The checks run every
:gc_memory_check_interval, which defaults to 10 seconds.
Queryable API
Use ETS match specifications to query entry fields, or {:in, keys} to look
up specific keys (see "{:in, keys} queries").
The adapter also accepts query: :expired to select expired entries.
Entries are stored as {:entry, key, value, touched, exp, tag} tuples, and
match specifications use this structure. You can write them directly or
build them with Ex2ms or Nebulex.Adapters.Local.QueryHelper.
# Using raw ETS match spec
iex> match_spec = [
...>   {
...>     {:entry, :"$1", :"$2", :_, :_, :_},
...>     [{:>, :"$2", 1}],
...>     [{{:"$1", :"$2"}}]
...>   }
...> ]
iex> MyCache.get_all(query: match_spec)
{:ok, [b: 2, c: 3]}

# Using Ex2ms for easier query building
iex> import Ex2ms
iex> match_spec = fun do
...>   {_, key, value, _, _, _} when value > 1 -> {key, value}
...> end
iex> MyCache.get_all(query: match_spec)
{:ok, [b: 2, c: 3]}
{:in, keys} queries
Queries with {:in, keys} (e.g., MyCache.get_all(in: keys)) look up the
requested keys directly through the table's key index, avoiding a
full-table scan. Lookup cost depends on the table type and the number of
entries stored under each key. Any term is a valid key, and duplicate keys
in the input are processed only once. Bear in mind:
	get_all behaves like fetch/2 on each key: if an entry is found in
the older generation, it is moved into the newer one, and expired
entries are lazily removed on read.
	count_all skips expired entries and leaves them in the table.
	delete_all removes the entries stored under the given keys, expired
ones included, but counts only the entries that had not expired.
	stream is read-only; it does not move entries across generations nor
remove expired ones.
	Keys are compared with the table's native key equality, the same as
the single-key commands: =:= on :set, :bag, and :duplicate_bag
tables, and == on :ordered_set tables (an entry stored under the
integer 1 matches the key 1.0). On :set and :ordered_set
tables an entry is counted or returned once, even when several given
keys alias it or when it is transiently present in both generations
while a concurrent read promotes it.

Building match specs with QueryHelper
Nebulex.Adapters.Local.QueryHelper builds ETS match specs from named
fields (:key, :value, :touched, :exp, and :tag), so you do not
need to write the internal entry tuple yourself. It requires the optional
:ex2ms dependency.
use Nebulex.Adapters.Local.QueryHelper

# Get the values of the entries whose key is an integer greater than 10
ms = match_spec key: k, value: v, where: is_integer(k) and k > 10, select: v
MyCache.get_all!(query: ms)
Use these match specs with get_all, count_all, delete_all, and
stream. See Nebulex.Adapters.Local.QueryHelper for the full syntax and
more examples, and its
"Tags and caching decorators"
section for using it with Nebulex.Caching decorators and cache references.
Tagging entries
Use the :tag option to attach any Elixir term to an entry. You can then
query or delete the entries with that tag. Entries written without a tag
have a nil tag.
MyCache.put("user:123:profile", profile, tag: {:user, 123})
MyCache.put_all([a: 1, b: 2, c: 3], tag: :group_a)

use Nebulex.Adapters.Local.QueryHelper

# Get the values of the entries tagged :group_a
ms = match_spec value: v, tag: t, where: t == :group_a, select: v
MyCache.get_all!(query: ms)
#=> [1, 2, 3]

# Delete all the entries of user 123
ms = match_spec tag: t, where: t == {:user, 123}
MyCache.delete_all!(query: ms)
Tags are metadata, not part of the key. With the default :set table type,
writing the same key replaces its entry regardless of the tag.
With Ex2ms, match the tag as the last element of the entry tuple:
import Ex2ms

match_spec = fun do
  {_, _, value, _, _, tag} when tag == :group_a -> value
end

MyCache.get_all!(query: match_spec)
#=> [1, 2, 3]
Transaction API
This adapter implements Nebulex.Adapter.Transaction using
Nebulex.Locks, which keeps the locks in ETS on the local node.
The transaction command accepts the following options:
	:keys (list of term/0) - The list of keys to lock. If empty or not provided, a global lock
is used. For better concurrency, always specify the keys involved
in the transaction to enable fine-grained locking. The default value is [].

	:retries (:infinity | non_neg_integer/0) - The number of times to retry acquiring locks before giving up.
If set to :infinity, the process will retry indefinitely until
locks are acquired. The default value is 3.

	:retry_interval (non_neg_integer/0 | (attempt :: non_neg_integer() -> non_neg_integer())) - The time in milliseconds to wait between lock acquisition retries.
Can be either:
	A timeout value (non_neg_integer()) - A fixed interval. When using
a non-negative integer, a small random jitter is added to prevent
thundering herd issues.
	An anonymous function - Receives the current attempt number
(0-indexed) and must return a non-negative integer representing the
interval in milliseconds. No jitter is added, giving you full control
over the retry strategy. Returning 0 results in immediate retry with
no delay.

Examples:
# Fixed interval with automatic jitter
retry_interval: 10

# Exponential backoff
retry_interval: fn attempt ->
  round(min(100 * :math.pow(2, attempt), 5000))
end

# Linear backoff
retry_interval: fn attempt -> 10 + (attempt * 50) end

# Immediate retry on first attempt, then backoff
retry_interval: fn
  0 -> 0
  attempt -> attempt * 100
end

# Custom strategy with manual jitter
retry_interval: fn attempt ->
  base = 100 * attempt
  jitter = :rand.uniform(max(base, 1))
  base + jitter
end
The default value is 10.

	:lock_timeout (timeout/0) - The maximum time in milliseconds a lock can be held before being
considered stale. Stale locks (from crashed processes or timeouts)
are automatically cleaned up during acquisition attempts. The default value is 30000.


To customize the locks manager, set the :lock_opts option when starting
the cache (see the configuration options above).
Extended API (extra functions)
The adapter adds these functions to the Nebulex.Cache API.
Creating new generations:
MyCache.new_generation()
MyCache.new_generation(gc_interval_reset: false)
Retrieving the current generations:
MyCache.generations()
Retrieving the newer generation:
MyCache.newer_generation()

          @type mem_check_interval() ::
  pos_integer()
  | (limit :: :size | :memory,
     current :: non_neg_integer(),
     max :: non_neg_integer() ->
       timeout :: pos_integer())


      


The type for the :gc_memory_check_interval option value.
The :gc_memory_check_interval value can be:
	A positive integer with the time in milliseconds.
	An anonymous function to call in runtime and must return the next interval
in milliseconds. The function receives three arguments:	The first argument is an atom indicating the limit, whether it is
:size or :memory.
	The second argument is the current value for the limit. For example,
if the limit in the first argument is :size, the second argument tells
the current cache size (number of entries in the cache). If the limit is
:memory, it means the recent cache memory in bytes.
	The third argument is the maximum limit provided in the configuration.
When the limit in the first argument is :size, it is the :max_size.
On the other hand, if the limit is :memory, it is the
:allocated_memory.

A simple, ETS-based locking mechanism for local synchronization.
This module provides a lightweight locking system suitable for single-node
use cases, such as implementing transactions in local cache adapters. It
uses ETS for lock storage with atomic operations for acquiring and releasing
locks.
Features
	Atomic lock acquisition - Uses insert_new for atomic operations.
	Deadlock prevention - Locks are acquired in sorted key order.
	Dual stale lock cleanup - Automatic cleanup via two mechanisms:	On-demand: During lock acquisition attempts
	Periodic: Background cleanup at configurable intervals


	Fine-grained locking - Lock specific keys for better concurrency.
	Retry with jitter - Configurable retries with jitter to prevent
thundering herd.
	Scalable cleanup - Batch-based cleanup using ETS continuation to
handle large numbers of locks efficiently.

Usage
The module supports two modes of operation:
Named mode (recommended)
When you provide a :name option, both the GenServer and the ETS table
are registered with that name, allowing direct access without calling
get_table/1:
# Start with a name
children = [
  {Nebulex.Locks, name: MyApp.Locks}
]

Supervisor.start_link(children, strategy: :one_for_one)

# Use the name directly for acquire/release
case Nebulex.Locks.acquire(MyApp.Locks, [:key1, :key2], retries: 5) do
  :ok ->
    try do
      # Critical section
    after
      Nebulex.Locks.release(MyApp.Locks, [:key1, :key2])
    end

  {:error, :timeout} ->
    # Failed to acquire locks
end
Anonymous mode
When :name is not provided or is nil, the GenServer starts unnamed
and you must use get_table/1 to obtain the table reference:
# Start without a name
{:ok, pid} = Nebulex.Locks.start_link([])

# Get the table reference
table = Nebulex.Locks.get_table(pid)

# Use the table reference
Nebulex.Locks.acquire(table, [:key1], retries: 3)
Start Options
	:name (atom/0) - Optional name to register both the GenServer and ETS table.
When provided, allows direct access to the locks table using the name.
When nil or not provided, the GenServer starts unnamed.

	:cleanup_interval (timeout/0) - The interval in milliseconds for the periodic cleanup of stale locks.
Stale locks are detected by checking if the owner process is alive and
if the lock has exceeded the :lock_timeout. The default value is 300000.

	:cleanup_batch_size (pos_integer/0) - The number of locks to process per batch during periodic cleanup.
Larger values reduce iteration overhead but increase memory usage
during cleanup. Smaller values reduce memory spikes but increase
the number of ETS select operations. The default value is 100.

	:init_callback - An optional callback MFA (module, function, arguments) to be invoked
after the locks table is created during GenServer initialization.
The callback is invoked as apply(module, function, [table | args]),
where table is the newly created ETS locks table prepended to the
provided argument list. The return value is ignored.
This is useful for integration scenarios where the locks table reference
needs to be stored in external state, such as an adapter's metadata table.
Example
# Store the locks table in the adapter's metadata
{Nebulex.Locks, [
  name: MyApp.Locks,
  init_callback: {MyApp, :init, [:some_arg]}
]}

# Will call: MyApp.init(table, :some_arg)


Lock Entry Structure
Locks are stored in ETS as records:
{:lock, lock_key, owner_pid, timestamp, timeout}
Where:
	lock_key - The key being locked (sorted to prevent deadlocks).
	owner_pid - The PID of the process holding the lock.
	timestamp - When the lock was acquired (for stale detection).
	timeout - Maximum time the lock can be held before being stale.

Stale Lock Detection and Cleanup
This module implements a defense-in-depth approach to stale lock cleanup,
combining two complementary mechanisms:
On-Demand Cleanup
When a process attempts to acquire a lock and finds an existing lock, it
checks if the lock is stale before failing the acquisition:
	Dead process detection: Uses Process.alive?/1 to detect if the
lock owner has crashed.
	Timeout detection: Compares the lock's timestamp with its configured
lock_timeout to detect locks held longer than allowed.

If a stale lock is detected, it is immediately removed and the acquiring
process can obtain the lock. This ensures low latency for lock acquisition
on frequently accessed keys.
Periodic Cleanup
A background cleanup process runs at the configured :cleanup_interval
(default: 5 minutes) to proactively remove stale locks. Locks are processed
in batches (default: 100 locks per batch) using ETS continuation to avoid
loading the entire table into memory at once.
This periodic cleanup ensures that stale locks from infrequently accessed
keys don't accumulate in memory, preventing memory leaks.
Why Two Mechanisms?
	On-demand cleanup: Provides immediate cleanup for actively used keys
with minimal latency.
	Periodic cleanup: Prevents memory leaks by cleaning up locks for keys
that are no longer accessed.
	Together: Ensures robust cleanup under all usage patterns.

Performance Characteristics
Lock Acquisition and Release
	No GenServer bottleneck: Lock operations hit ETS directly via atomic
insert_new operations. Only get_table/1 requires a GenServer call.
	High concurrency: Public ETS table with :write_concurrency and
:read_concurrency enabled.

Lock Fairness
	No FIFO guarantee: When multiple processes compete for the same lock,
the winner is determined by ETS race conditions and scheduler timing.
	Practical fairness: With retry intervals and jitter, starvation is
virtually impossible in practice.
	Trade-off: Prioritizes performance over strict ordering. For use cases
requiring FIFO fairness, consider sleeplocks or a queue-based approach.


      


      
        Summary


  
    Functions
  


    
      
        acquire(table, keys, opts \\ [])

      


        Attempts to acquire locks for the given keys.



    


    
      
        child_spec(init_arg)

      


        Returns a specification to start this module under a supervisor.



    


    
      
        get_table(server)

      


        Returns the locks table from a running GenServer.



    


    
      
        lock(args \\ [])

      


    


    
      
        lock(record, args)

      


    


    
      
        release(table, keys)

      


        Releases locks for the given keys.



    


    
      
        start_link(opts)

      


        Starts the locks GenServer.



    





      


      
        Functions


        


    

  
    
      
    
    
      acquire(table, keys, opts \\ [])



        
          
        

    

  


  

      

          @spec acquire(:ets.table(), [any()], keyword()) :: :ok | {:error, :timeout}


      


Attempts to acquire locks for the given keys.
Locks are acquired atomically in a sorted order to prevent deadlocks.
If any lock cannot be acquired, all partially acquired locks are released
and the operation is retried according to the options.
The first parameter can be either a named table (atom) or a table reference.
Options
	:keys (list of term/0) - The list of keys to lock. If empty or not provided, a global lock
is used. For better concurrency, always specify the keys involved
in the transaction to enable fine-grained locking. The default value is [].

	:retries (:infinity | non_neg_integer/0) - The number of times to retry acquiring locks before giving up.
If set to :infinity, the process will retry indefinitely until
locks are acquired. The default value is 3.

	:retry_interval (non_neg_integer/0 | (attempt :: non_neg_integer() -> non_neg_integer())) - The time in milliseconds to wait between lock acquisition retries.
Can be either:
	A timeout value (non_neg_integer()) - A fixed interval. When using
a non-negative integer, a small random jitter is added to prevent
thundering herd issues.
	An anonymous function - Receives the current attempt number
(0-indexed) and must return a non-negative integer representing the
interval in milliseconds. No jitter is added, giving you full control
over the retry strategy. Returning 0 results in immediate retry with
no delay.

Examples:
# Fixed interval with automatic jitter
retry_interval: 10

# Exponential backoff
retry_interval: fn attempt ->
  round(min(100 * :math.pow(2, attempt), 5000))
end

# Linear backoff
retry_interval: fn attempt -> 10 + (attempt * 50) end

# Immediate retry on first attempt, then backoff
retry_interval: fn
  0 -> 0
  attempt -> attempt * 100
end

# Custom strategy with manual jitter
retry_interval: fn attempt ->
  base = 100 * attempt
  jitter = :rand.uniform(max(base, 1))
  base + jitter
end
The default value is 10.

	:lock_timeout (timeout/0) - The maximum time in milliseconds a lock can be held before being
considered stale. Stale locks (from crashed processes or timeouts)
are automatically cleaned up during acquisition attempts. The default value is 30000.


Examples
# Using a named table
iex> {:ok, _pid} = Nebulex.Locks.start_link(name: MyLocks)
iex> Nebulex.Locks.acquire(MyLocks, [:key1, :key2])
:ok

# Using a table reference
iex> {:ok, pid} = Nebulex.Locks.start_link([])
iex> table = Nebulex.Locks.get_table(pid)
iex> Nebulex.Locks.acquire(table, [:key1])
:ok

Returns a specification to start this module under a supervisor.
See Supervisor.

          @spec get_table(GenServer.server()) :: :ets.table()


      


Returns the locks table from a running GenServer.
This function is needed when starting the GenServer without a name.
For named GenServers, you can use the name directly with acquire/3
and release/2.
Examples
# Named mode - table name is the same as GenServer name
iex> {:ok, _pid} = Nebulex.Locks.start_link(name: MyLocks)
iex> table = Nebulex.Locks.get_table(MyLocks)
iex> table == MyLocks
true

# Anonymous mode - returns a table reference
iex> {:ok, pid} = Nebulex.Locks.start_link([])
iex> table = Nebulex.Locks.get_table(pid)
iex> is_reference(table)
true

          @spec release(:ets.table(), [any()]) :: :ok


      


Releases locks for the given keys.
This function is typically called in an after block to ensure
locks are released even if an exception occurs.
This API assumes trusted callers: it does not verify lock ownership
when deleting lock entries. Releasing keys not owned by the current
process is considered undefined behavior.
The first parameter can be either a named table (atom) or a table reference.
Examples
# Using a named table
iex> {:ok, _pid} = Nebulex.Locks.start_link(name: MyLocks)
iex> Nebulex.Locks.acquire(MyLocks, [:key1, :key2])
:ok
iex> Nebulex.Locks.release(MyLocks, [:key1, :key2])
:ok

# Using a table reference
iex> {:ok, pid} = Nebulex.Locks.start_link([])
iex> table = Nebulex.Locks.get_table(pid)
iex> Nebulex.Locks.acquire(table, [:key1])
:ok
iex> Nebulex.Locks.release(table, [:key1])
:ok

  



  
    
      
    
    
      start_link(opts)



        
          
        

    

  


  

      

          @spec start_link(keyword()) :: GenServer.on_start()


      


Starts the locks GenServer.
Options
	:name (atom/0) - Optional name to register both the GenServer and ETS table.
When provided, allows direct access to the locks table using the name.
When nil or not provided, the GenServer starts unnamed.

	:cleanup_interval (timeout/0) - The interval in milliseconds for the periodic cleanup of stale locks.
Stale locks are detected by checking if the owner process is alive and
if the lock has exceeded the :lock_timeout. The default value is 300000.

	:cleanup_batch_size (pos_integer/0) - The number of locks to process per batch during periodic cleanup.
Larger values reduce iteration overhead but increase memory usage
during cleanup. Smaller values reduce memory spikes but increase
the number of ETS select operations. The default value is 100.

	:init_callback - An optional callback MFA (module, function, arguments) to be invoked
after the locks table is created during GenServer initialization.
The callback is invoked as apply(module, function, [table | args]),
where table is the newly created ETS locks table prepended to the
provided argument list. The return value is ignored.
This is useful for integration scenarios where the locks table reference
needs to be stored in external state, such as an adapter's metadata table.
Example
# Store the locks table in the adapter's metadata
{Nebulex.Locks, [
  name: MyApp.Locks,
  init_callback: {MyApp, :init, [:some_arg]}
]}

# Will call: MyApp.init(table, :some_arg)



  


        

      


  

    
Nebulex.Adapters.Local.Generation 
    



      
This module implements the generation manager and garbage collector.
The generation manager creates cache generations and schedules the deletion
of retired generation tables. The adapter stores new entries in the newer
generation and promotes entries from the older generation when they are
fetched.
Generations rotate on the configured :gc_interval, when a size or memory
check reaches its threshold, or when a caller explicitly requests a new
generation.
When a new generation is created, the oldest one is removed from the active
generations at once, so new operations no longer see it. Its tables are
deleted after :gc_cleanup_delay, which gives operations that already hold
a reference to them time to finish.

      


      
        Summary


  
    Types
  


    
      
        opts()

      


    


    
      
        server_ref()

      


    


    
      
        t()

      


    





  
    Functions
  


    
      
        child_spec(init_arg)

      


        Returns a specification to start this module under a supervisor.



    


    
      
        delete_all(server_ref)

      


        Removes or flushes all entries from the cache (including all its generations).



    


    
      
        get_state(server_ref)

      


        A convenience function for retrieving the state.



    


    
      
        list(server_ref)

      


        Returns the list of the generations in the form [newer, older].



    


    
      
        memory_info(server_ref)

      


        Returns the memory info in a tuple form {used_mem, total_mem}.



    


    
      
        new(server_ref, opts \\ [])

      


        Creates a new cache generation. Once the max number of generations
is reached, when a new generation is created, the oldest one is
deleted.



    


    
      
        newer(server_ref)

      


        Returns the newer generation.



    


    
      
        realloc(server_ref, size)

      


        Reallocates the block of memory that was previously allocated for the given
server_ref with the new size. In other words, reallocates the max memory
size for a cache generation.



    


    
      
        reset_gc_interval(server_ref)

      


        Resets the GC interval.



    


    
      
        server(server_ref)

      


        Returns the PID of the GC server for the given server_ref.



    


    
      
        start_link(opts)

      


        Starts the garbage collector for the built-in local cache adapter.



    





      


      
        Types


        


  
    
      
    
    
      opts()



        
          
        

    

  


  

      

          @type opts() :: Nebulex.Cache.opts()


      



  



  
    
      
    
    
      server_ref()



        
          
        

    

  


  

      

          @type server_ref() :: pid() | atom() | :ets.tid()


      



  



  
    
      
    
    
      t()



        
          
        

    

  


  

      

          @type t() :: %Nebulex.Adapters.Local.Generation{
  allocated_memory: term(),
  backend: term(),
  backend_opts: term(),
  cache: term(),
  gc_cleanup_delay: term(),
  gc_healthcheck_ref: term(),
  gc_heartbeat_ref: term(),
  gc_interval: term(),
  gc_memory_check_interval: term(),
  max_size: term(),
  meta_tab: term(),
  name: term(),
  stats_counter: term(),
  telemetry: term(),
  telemetry_prefix: term()
}


      



  


        

      

      
        Functions


        


  
    
      
    
    
      child_spec(init_arg)



        
          
        

    

  


  

Returns a specification to start this module under a supervisor.
See Supervisor.

  



  
    
      
    
    
      delete_all(server_ref)



        
          
        

    

  


  

      

          @spec delete_all(server_ref()) :: :ok


      


Removes or flushes all entries from the cache (including all its generations).
Example
Nebulex.Adapters.Local.Generation.delete_all(MyCache)

  



  
    
      
    
    
      get_state(server_ref)



        
          
        

    

  


  

      

          @spec get_state(server_ref()) :: t()


      


A convenience function for retrieving the state.

  



  
    
      
    
    
      list(server_ref)



        
          
        

    

  


  

      

          @spec list(server_ref()) :: [:ets.tid()]


      


Returns the list of the generations in the form [newer, older].
Example
Nebulex.Adapters.Local.Generation.list(MyCache)

  



  
    
      
    
    
      memory_info(server_ref)



        
          
        

    

  


  

      

          @spec memory_info(server_ref()) ::
  {used_mem :: non_neg_integer(), total_mem :: non_neg_integer()}


      


Returns the memory info in a tuple form {used_mem, total_mem}.
Example
Nebulex.Adapters.Local.Generation.memory_info(MyCache)

  



    

  
    
      
    
    
      new(server_ref, opts \\ [])



        
          
        

    

  


  

      

          @spec new(server_ref(), opts()) :: :ok


      


Creates a new cache generation. Once the max number of generations
is reached, when a new generation is created, the oldest one is
deleted.
Options
	:gc_interval_reset (boolean/0) - Whether the :gc_interval should be reset or not. The default value is true.

Example
Nebulex.Adapters.Local.Generation.new(MyCache)

Nebulex.Adapters.Local.Generation.new(MyCache, gc_interval_reset: false)

  



  
    
      
    
    
      newer(server_ref)



        
          
        

    

  


  

      

          @spec newer(server_ref()) :: :ets.tid()


      


Returns the newer generation.
Example
Nebulex.Adapters.Local.Generation.newer(MyCache)

  



  
    
      
    
    
      realloc(server_ref, size)



        
          
        

    

  


  

      

          @spec realloc(server_ref(), pos_integer()) :: :ok


      


Reallocates the block of memory that was previously allocated for the given
server_ref with the new size. In other words, reallocates the max memory
size for a cache generation.
Example
Nebulex.Adapters.Local.Generation.realloc(MyCache, 1_000_000)

  



  
    
      
    
    
      reset_gc_interval(server_ref)



        
          
        

    

  


  

      

          @spec reset_gc_interval(server_ref()) :: :ok


      


Resets the GC interval.
Example
Nebulex.Adapters.Local.Generation.reset_gc_interval(MyCache)

  



  
    
      
    
    
      server(server_ref)



        
          
        

    

  


  

      

          @spec server(server_ref()) :: pid()


      


Returns the PID of the GC server for the given server_ref.
Example
Nebulex.Adapters.Local.Generation.server(MyCache)

  



  
    
      
    
    
      start_link(opts)



        
          
        

    

  


  

      

          @spec start_link(opts()) :: GenServer.on_start()


      


Starts the garbage collector for the built-in local cache adapter.

  


        

      


  

    
Nebulex.Adapters.Local.Options 
    



      
Option definitions for the local adapter.

      


      
        Summary


  
    Functions
  


    
      
        adapter_options_docs()

      


    


    
      
        gc_runtime_options_docs()

      


    


    
      
        validate_adapter_opts!(opts)

      


    


    
      
        validate_gc_runtime_opts!(opts)

      adapter_options_docs()



        
          
        

    

  


  

      

          @spec adapter_options_docs() :: binary()


      



  



  
    
      
    
    
      gc_runtime_options_docs()



        
          
        

    

  


  

      

          @spec gc_runtime_options_docs() :: binary()


      



  



  
    
      
    
    
      validate_adapter_opts!(opts)



        
          
        

    

  


  

      

          @spec validate_adapter_opts!(keyword()) :: keyword()


      



  



  
    
      
    
    
      validate_gc_runtime_opts!(opts)



        
          
        

    

  


  

      

          @spec validate_gc_runtime_opts!(keyword()) :: keyword()


      



  


        

      


  

    
Nebulex.Adapters.Local.QueryHelper 
    



      
Builds ETS match specifications for Nebulex.Adapters.Local from named
fields, so you do not need to write the internal entry tuple
{:entry, key, value, touched, exp, tag} yourself.
The match_spec/1 macro turns the named fields into the entry tuple and
uses Ex2ms to generate the match spec. It requires the optional :ex2ms
dependency.
Getting Started
The simplest way to use this module is with use:
defmodule MyCache.Queries do
  use Nebulex.Adapters.Local.QueryHelper

  def by_key(key) do
    match_spec key: k, value: v, where: k == key, select: v
  end

  def by_tag(tag) do
    match_spec tag: t, where: t == tag, select: true
  end
end
Examples
# Simple match on key
match_spec key: k, value: v, where: k == :foo, select: v

# Match with tag
match_spec key: k, value: v, tag: t,
           where: t == :important,
           select: {k, v}

# Complex guards
match_spec key: k, value: v,
           where: is_integer(k) and k > 10,
           select: {k, v}

# Without guards
match_spec key: k, value: v, select: {k, v}

# Return entire entry
match_spec key: k, value: v, where: k > 100, select: :"$_"

# Match only on specific fields
match_spec tag: t, where: t == :important, select: true

# Complex conditions
match_spec key: k, value: v, tag: t, exp: e,
           where: k > t and e != :infinity,
           select: {k, v, e}
Supported field bindings
	:key - The cache key
	:value - The cached value
	:touched - Timestamp when entry was last touched
	:exp - Expiration timestamp (or :infinity)
	:tag - Optional tag metadata

Fields not mentioned in the pattern will be wildcarded with _.
Clauses
	Field bindings (:key, :value, :tag, :touched, :exp) - Bind entry
fields to variables.
	:where - Optional guard conditions (supports all ETS guard functions).
	:select - What to return (optional, defaults to true).

Using match specs with cache operations
Use the match specs with get_all, count_all, delete_all, and
stream:
use Nebulex.Adapters.Local.QueryHelper

# Get all values where the key is an integer greater than 10
ms = match_spec key: k, value: v, where: is_integer(k) and k > 10, select: v
MyCache.get_all!(query: ms)

# Count the entries with a specific tag
ms = match_spec tag: t, where: t == :user_session
MyCache.count_all!(query: ms)

# Delete expired entries (exp is not :infinity and less than now)
now = System.system_time(:millisecond)
ms = match_spec exp: e, where: e != :infinity and e < now
MyCache.delete_all!(query: ms)

# Stream entries in batches
ms = match_spec value: v, where: is_binary(v), select: v
MyCache.stream!(query: ms) |> Enum.take(100)
To reuse queries, put them in a module:
defmodule MyApp.CacheQueries do
  use Nebulex.Adapters.Local.QueryHelper

  # Find all entries for a specific user
  def user_entries(user_id) do
    match_spec tag: t, where: t == {:user, user_id}, select: :"$_"
  end

  # Find entries expiring within the next hour (not expired yet)
  def expiring_soon do
    now = System.system_time(:millisecond)
    cutoff = now + :timer.hours(1)

    match_spec exp: e, where: e != :infinity and e > now and e < cutoff
  end

  # Filter by tag and the time the entry was last written or touched
  def recent_tagged_entries(tag, min_time) do
    match_spec key: k,
               value: v,
               tag: t,
               touched: ts,
               where: t == tag and ts > min_time,
               select: {k, v}
  end
end

MyApp.Cache.get_all!(query: MyApp.CacheQueries.user_entries(123))
MyApp.Cache.delete_all!(query: MyApp.CacheQueries.expiring_soon())
Tags and caching decorators
The Nebulex.Caching decorators can tag the entries they write, and
cache_evict can take a QueryHelper match spec to evict entries by tag or
by reference.
Tagging entries from decorators
Pass the tag through the decorator's :opts option:
defmodule MyApp.UserCache do
  use Nebulex.Caching, cache: MyApp.Cache
  use Nebulex.Adapters.Local.QueryHelper

  # Cache user data, tagged with the user ID
  @decorate cacheable(key: {:user, user_id}, opts: [tag: {:user, user_id}])
  def get_user(user_id) do
    # fetch user from database
    {:ok, user}
  end

  # Cache user permissions under their own key, with the same tag
  @decorate cacheable(key: {:permissions, user_id}, opts: [tag: {:user, user_id}])
  def get_user_permissions(user_id) do
    # fetch permissions from database
    {:ok, permissions}
  end

  # Store session data, tagged as a session
  @decorate cache_put(key: session_id, opts: [tag: :sessions])
  def create_session(session_id, data) do
    data
  end
end
Tags are metadata, not part of the key. With the default :set table
type, writing the same key replaces its entry regardless of the tag, so
give each kind of data its own key.
Evicting entries by tag
Use cache_evict with a function that returns the match spec:
defmodule MyApp.UserCache do
  use Nebulex.Caching, cache: MyApp.Cache
  use Nebulex.Adapters.Local.QueryHelper

  # ... cacheable functions as above ...

  # Evict all cached data for a specific user
  @decorate cache_evict(query: &evict_user_query/1)
  def invalidate_user(user_id) do
    :ok
  end

  defp evict_user_query(%{args: [user_id]} = _context) do
    match_spec tag: t, where: t == {:user, user_id}
  end
end
The same approach clears all the sessions of a user, or all sessions:
defmodule MyApp.Sessions do
  use Nebulex.Caching, cache: MyApp.Cache
  use Nebulex.Adapters.Local.QueryHelper

  @decorate cache_put(key: session_id, opts: [tag: {:session, user_id}])
  def store_session(user_id, session_id, data) do
    data
  end

  # Evict all sessions of a user when they log out
  @decorate cache_evict(query: &evict_user_sessions_query/1)
  def logout_user(user_id) do
    :ok
  end

  # Evict all sessions of all users (e.g., during maintenance)
  @decorate cache_evict(query: &evict_all_sessions_query/1)
  def clear_all_sessions do
    :ok
  end

  defp evict_user_sessions_query(%{args: [user_id]} = _context) do
    match_spec tag: t, where: t == {:session, user_id}
  end

  defp evict_all_sessions_query(_context) do
    match_spec tag: t, where: is_tuple(t) and elem(t, 0) == :session
  end
end
Evicting cache references
When a decorator caches a value under several keys with the :references
option, keyref_match_spec/2 finds the reference entries that point to a
key, so cache_evict can remove them all at once:
defmodule MyApp.UserAccounts do
  use Nebulex.Caching, cache: MyApp.Cache
  use Nebulex.Adapters.Local.QueryHelper

  @decorate cacheable(key: user_id)
  def get_user_account(user_id) do
    fetch_user(user_id)
  end

  @decorate cacheable(key: email, references: &(&1 && &1.id))
  def get_user_account_by_email(email) do
    fetch_user_by_email(email)
  end

  @decorate cacheable(key: token, references: &(&1 && &1.id))
  def get_user_account_by_token(token) do
    fetch_user_by_token(token)
  end

  # Evict the user and all the lookups (by email and token) that
  # reference it
  @decorate cache_evict(key: user_id, query: &invalidate_refs/1)
  def update_user_account(user_id, attrs) do
    :ok
  end

  defp invalidate_refs(%{args: [user_id | _]} = _context) do
    keyref_match_spec(user_id)
  end
end
Internal entry format
The internal ETS entry is an Erlang record with the structure:
{:entry, key, value, touched, exp, tag}
The match_spec/1 macro builds this tuple for you.

        __using__(opts)

      


        Imports the query helper macros and Ex2ms for building match specifications.



    


    
      
        keyref_match_spec(referenced_key, opts \\ [])

      


        Builds a match spec for finding cache reference entries (keyrefs).



    


    
      
        match_spec(opts)

      


        Builds an ETS match specification from a SQL-like declarative syntax.

        (macro)


        
          
        

    

  


  

Imports the query helper macros and Ex2ms for building match specifications.
When you use this module, it automatically imports:
	Ex2ms - For the underlying match spec generation (fun do ... end)
	Nebulex.Adapters.Local.QueryHelper - For the match_spec/1 macro

Usage
defmodule MyModule do
  use Nebulex.Adapters.Local.QueryHelper

  def my_query do
    match_spec key: k, value: v, where: k == :foo, select: v
  end
end
Alternative: Manual Import
If you prefer more control, you can import modules manually:
defmodule MyModule do
  import Ex2ms
  import Nebulex.Adapters.Local.QueryHelper

  def my_query do
    match_spec key: k, value: v, where: k == :foo, select: v
  end
end
Note
The match_spec/1 macro requires Ex2ms to be available. If you don't use
this module or manually import Ex2ms, you'll get a compilation error when
trying to use match_spec/1.

  



    

  
    
      
    
    
      keyref_match_spec(referenced_key, opts \\ [])



        
          
        

    

  


  

      

          @spec keyref_match_spec(term(), keyword()) :: :ets.match_spec()


      


Builds a match spec for finding cache reference entries (keyrefs).
This is useful for invalidating all reference keys that point to a specific
referenced key. Cache references are created using the keyref/2 function
in Nebulex caching decorators.
The match spec returns the reference key (the cache key that points to the
referenced key). This works seamlessly with get_all/1, delete_all/1, and
count_all/1 operations.
Parameters
	referenced_key - The key that references point to (required).
	opts - Optional keyword list:	:cache - Filter references to a specific cache (optional). When not
provided, matches references in any cache (including nil for local
references).



Examples
# Delete all reference entries pointing to a specific key (any cache)
ms = keyref_match_spec(:user_123)
MyCache.delete_all!(query: ms)

# Delete reference entries pointing to a key in a specific cache
ms = keyref_match_spec(:user_123, cache: MyApp.UserCache)
MyCache.delete_all!(query: ms)

# Count how many references point to a key
ms = keyref_match_spec(:product_456)
MyCache.count_all!(query: ms)

# Get all cache keys that are references to a specific key
ms = keyref_match_spec(:user_123)
reference_keys = MyCache.get_all!(query: ms)
Background
When using the :references option with caching decorators, Nebulex stores
reference entries as keyref records with the structure:
{:"$nbx_keyref_spec", cache, key, ttl}. This function helps you query and
clean up these reference entries.
See also
	Nebulex.Caching - For information about cache references and the
:references option.

        (macro)


        
          
        

    

  


  

Builds an ETS match specification from a SQL-like declarative syntax.
The macro accepts a keyword list with field bindings, optional guards
(:where), and a return expression (:select).
Requirements
This macro requires Ex2ms to be available. The recommended approach is to
use this module:
use Nebulex.Adapters.Local.QueryHelper
Alternatively, you can manually import both modules:
import Ex2ms
import Nebulex.Adapters.Local.QueryHelper
Syntax
match_spec field: var, ..., where: guards, select: return_value
Where:
	Field bindings (:key, :value, :tag, :touched, :exp) bind entry
fields to variables.
	:where - Optional guard clause with conditions.
	:select - Optional return expression (defaults to true).

Examples
# Match all entries where key equals :foo
match_spec key: k, value: v, where: k == :foo, select: v

# Match entries with specific tag
match_spec key: k, tag: t, where: t == :important, select: k

# Complex guards and return values
match_spec key: k, value: v, exp: e,
           where: is_integer(v) and e != :infinity,
           select: {k, v, e}

# Without guards
match_spec key: k, value: v, select: {k, v}

# Return the entire entry
match_spec value: v, tag: t, where: t == :foo, select: :"$_"

# Using default select: true (useful for count_all/delete_all)
match_spec tag: t, where: t == :important
# Same as: match_spec tag: t, where: t == :important, select: true
Notes
	Fields not mentioned will be wildcarded (:_).
	The order of fields doesn't matter.
	Guards support all ETS guard functions (via Ex2ms).
	The :select clause is optional and defaults to true.

